@echo off
@if not "%OS%"=="Windows_NT" goto :EXIT

rem ****************************************************************************
rem 11/10/2000 Dmitri Levin, Protech Systems
rem ****************************************************************************

set DLC=D:\DLC
set database-name=cats
set database-dir=d:\apeasdb

rem Here I make backup to disk
set backup-dir=d:\backup
set devce-name=%backup-dir%\cats

rem Name of the database server in ProControl
set ProControl-db-name=APEAS

set log-file=%backup-dir%\backup.log
set backup-param=-com -red 5 -scan
set on-line=
set line=****************************************************************************

rem ****************************************************************
rem Main block
rem ****************************************************************

echo %line% >> %log-file%
date /T >> %log-file%
echo %line% >> %log-file%
call :PROCEDURE-TIME
echo Backup Start --- %curr-time% >> %log-file%

rem ************ Stop database ************
%dlc%\bin\pccmd.exe database status %ProControl-db-name%
if "%ERRORLEVEL%"=="0" %dlc%\bin\pccmd.exe database stop %ProControl-db-name%

rem ************ Backup ************
"%DLC%\bin\_dbutil" probkup %database-dir%\%database-name% %devce-name% %backup-param% >> %log-file%

rem ************ Start database ************
%dlc%\bin\pccmd.exe database status %ProControl-db-name%
if not "%ERRORLEVEL%"=="0" %dlc%\bin\pccmd.exe database start %ProControl-db-name%

call :PROCEDURE-TIME
echo . >> %log-file%
echo Backup End --- %curr-time% >> %log-file%
echo . >> %log-file%

goto :EXIT

rem ****************************************************************
rem TIME PROCEDURE
rem ****************************************************************
:PROCEDURE-TIME

for /f %%A in ( 'time /t' ) do set curr-time=%%A

goto :EXIT

:EXIT

1